@ECHO OFF
REM *****************************************************************
REM *** MAJ Septembre 2006
REM *** Prise en compte de PPE: copie des fichiers d'install
REM *** + mise à jour de la version = celle de PP2000
REM ***
REM *** MAJ Mars 2007
REM *** Récupération de la version de PP2000 à installer sur le CD
REM ***************************************************************** 

If not exist g:\masters\ppr (
g:\outils\bin\endinst.exe /Title="PPS" /Text1="Mise a jour PPS pour le DCS" /Text2="Votre version de DCS ne contient pas PPS" 
goto fin
)

date /t >>g:\sys\log\ppscopy.log
time /t >>g:\sys\log\ppscopy.log

SET lang=FR

rem **** Récupération de la version de PP2000 à installer sur le CD
echo Recuperation de la version de PP2000 à installer >>g:\sys\log\ppscopy.log
for /f "tokens=2 delims==" %%i in ('find /i "VSOFT=" y:\outilrep\applic.ini') do set ppsver=%%i
echo Version de PP2000: %PPSVER% >>g:\sys\log\ppscopy.log

REM ****** CAS PPR ********
if exist g:\masters\pprnew\nul deltree /y g:\masters\pprnew >>g:\sys\log\ppscopy.log
md g:\masters\pprnew\sources >>g:\sys\log\ppscopy.log
if errorlevel=1 goto err

echo Copie des sources PP2000 dans pprnew >>g:\sys\log\ppscopy.log
xcopy y:\*.* g:\masters\pprnew\sources\*.* /E /I >>g:\sys\log\ppscopy.log
if errorlevel=1 goto err

md g:\masters\pprnew\config >>g:\sys\log\ppscopy.log
if errorlevel=1 goto err

echo Copie des scripts d'installation de PP2000 >>g:\sys\log\ppscopy.log
xcopy y:\DCS\CONFIG\*.* g:\masters\pprnew\config\*.* /E /I >>g:\sys\log\ppscopy.log
if errorlevel=1 goto err

Echo copy %PPSVER% >g:\masters\pprnew\sources\pp2000.flg

attrib -R g:\masters\pprnew /s /D

start /min /w fr g:\masters\pprnew\config\ppr.ori "\#" "%lang%" g:\masters\pprnew\config\ppr.reg
start /min /w fr g:\masters\pprnew\config\delppr.ori "\#" "%lang%" g:\masters\pprnew\config\delppr.reg

if exist g:\masters\pprold\nul rd /s /Q g:\masters\pprold
ren g:\masters\ppr pprold
if errorlevel=1 goto err
echo Renommage de pprnew en ppr >>g:\sys\log\ppscopy.log
ren g:\masters\pprnew ppr
if errorlevel=1 goto err
echo suppression du repertoire pprold >>g:\sys\log\ppscopy.log
rd /s /Q g:\masters\pprold
if errorlevel=1 goto err

REM ****** CAS PPE ********
echo Copie des scripts d'installation de PPE >>g:\sys\log\ppscopy.log
if exist g:\masters\ppenew\nul deltree /y g:\masters\ppenew >>g:\sys\log\ppscopy.log
md g:\masters\ppenew >>g:\sys\log\ppscopy.log
if errorlevel=1 goto err

xcopy y:\ppe\*.* g:\masters\ppenew\*.* /E /I >>g:\sys\log\ppscopy.log
if errorlevel=1 goto err

attrib -R g:\masters\ppenew /s /D

if exist g:\masters\ppeold\nul rd /s /Q g:\masters\ppeold
ren g:\masters\ppe ppeold
if errorlevel=1 goto err
ren g:\masters\ppenew ppe
if errorlevel=1 goto err
echo suppression du repertoire ppeold >>g:\sys\log\ppscopy.log
rd /s /Q g:\masters\ppeold
if errorlevel=1 goto err


REM ******* Mise à jour des Verref ********
echo Mise a jour du verrefp.ini >>g:\sys\log\ppscopy.log
setini g:\config\serveur\verrefp.ini PP2000 VERSION %PPSVER%
setini g:\config\serveur\verrefp.ini PP2000 MAJ S:\Masters\Ppr\Config\maj2k.ini
setini g:\config\serveur\verrefp.ini PPE VERSION %PPSVER%
setini g:\config\serveur\verrefp.ini PPE MAJ S:\Masters\Ppe\Config\maj2k.ini
if errorlevel=1 goto err

xcopy g:\config\serveur\verrefp.ini g:\Masters\ConfigServeur\config\serveur\verrefp.ini /Y /R
if errorlevel=1 goto err

g:\outils\bin\endinst.exe /Title="PPS" /Text1="Mise a jour PPS pour le DCS" /Text2="Fin d'execution"
echo Fin de la copie du CD >>g:\sys\log\ppscopy.log

goto fin

:err
echo erreur de copie des sources pps >g:\sys\log\errppr.flg
g:\outils\bin\endinst.exe /Title="PPS" /Text1="Mise a jour PPS pour le DCS" /Text2="erreur de copie des sources pps"  
goto fin

:fin